在vb.net的窗体属性中,有个属性叫TransparencyKey,它能决定在窗体上,哪种颜色所在的区域透明。
注意:TransparencyKey属性对窗体标题栏和外框无效。
如果我们想让窗体透明,如果你的窗体背景颜色是默认的,只要在窗体的Load事件加入一句代码就行:
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
Me.TransparencyKey = SystemColors.Control
End Sub
运行后,你会发现窗体除标题栏和外框都透明了。
如果你的窗体背景色是别的颜色,比如是红色,就将代码
Me.TransparencyKey = SystemColors.Control
改成:
Me.TransparencyKey = Color.Red
这么看来,建立一个透明窗体看来是很容易的一件事。但窗体透明有什么用呢?我首先想到就是做一个不规则的窗体。
我是这样设想的:
- 设置好窗体样式属性,去除窗体标题栏和外框
- 在窗体建立一个Picture控件并导入图片,这个图片需要透明的部分的RBG值为(255, 0, 255)
- 窗体的TransparencyKey设置为Color.FromArgb(255, 0, 255)
- 设置Picture的SizeMode属性 = PictureBoxSizeMode.AutoSiz
- 设置Picture的位置为(0,0),设置窗体的宽度和高度分别是图片的宽度和高度
我准备的图片是一个小黑狗,狗周围的颜色值=Color.FromArgb(255, 0, 255) 。如下图。
我这个黑狗图片在我的电脑路径是: d:\test\1.png
代码如下:
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
PictureBox1.ImageLocation = "d:\test\1.png" '设置图片
Me.FormBorderStyle = FormBorderStyle.None '设置窗体的无标题栏,无边框样式
PictureBox1.SizeMode = PictureBoxSizeMode.AutoSize '让图片控件尺寸随图片大小自动变化
PictureBox1.Location = New Point(0, 0)
Me.TransparencyKey = Color.FromArgb(255, 0, 255) '设置窗体需要透明的颜色
End Sub
Private Sub PictureBox1_SizeChanged(sender As Object, e As EventArgs) Handles PictureBox1.SizeChanged
'让窗体跟图片框尺寸一样大小
Me.Width = PictureBox1.Width
Me.Height = PictureBox1.Height
End Sub
Private Sub PictureBox1_DoubleClick(sender As Object, e As EventArgs) Handles PictureBox1.DoubleClick
Close()
End Sub
按F5测试运行,窗体上就会出现一条小黑狗,一个不规则的窗体就根据这个黑狗的图片就成功生成了。鼠标双击这个黑狗就可以关闭程序,只可惜不能用鼠标移动这只黑狗。
我们再导入相应API,再加上PictureBox1的鼠标移动事件,就可以实现用鼠标移动这条小狗,全部代码如下:
Public Class Form1
'以下是移动无标题栏窗体
Declare Auto Function ReleaseCapture Lib "user32.dll" Alias "ReleaseCapture" () As Boolean
'API ReleaseCapture函数是用来释放鼠标捕获的
Declare Auto Function SendMessage Lib "user32.dll" Alias "SendMessage" (ByVal hWnd As IntPtr, ByVal wMsg As Integer, ByVal wParam As Integer, ByVal lParam As Integer) As IntPtr
'向windows发送消息
Public Const WM_SYSCOMMAND As Integer = &H112&
Public Const SC_MOVE As Integer = &HF010&
Public Const HTCAPTION As Integer = &H2&
'以上是移动无标题栏窗体
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
PictureBox1.ImageLocation = "d:\test\1.png" '设置图片
Me.FormBorderStyle = FormBorderStyle.None '设置窗体的无标题栏,无边框样式
PictureBox1.SizeMode = PictureBoxSizeMode.AutoSize '让图片控件尺寸随图片大小自动变化
PictureBox1.Location = New Point(0, 0)
Me.TransparencyKey = Color.FromArgb(255, 0, 255) '设置窗体需要透明的颜色
End Sub
Private Sub PictureBox1_SizeChanged(sender As Object, e As EventArgs) Handles PictureBox1.SizeChanged
'让窗体跟图片框尺寸一样大小
Me.Width = PictureBox1.Width
Me.Height = PictureBox1.Height
End Sub
Private Sub PictureBox1_DoubleClick(sender As Object, e As EventArgs) Handles PictureBox1.DoubleClick
Close()
End Sub
Private Sub PictureBox1_MouseMove(sender As Object, e As MouseEventArgs) Handles PictureBox1.MouseMove
If e.Button = MouseButtons.Left Then '移动无标题栏窗体
ReleaseCapture()
SendMessage(Me.Handle, WM_SYSCOMMAND, SC_MOVE + HTCAPTION, 0)
End If
End Sub
End Class
以上代码在 visual studio 2022 测试成功。运行结果就是出现下面这只小黑狗。